CMakeLists.txt

#
# SPDX-License-Identifier: Apache-2.0
#

# ##############################################################################
# Project setup
# ##############################################################################
cmake_minimum_required(VERSION 3.8)
project(gr-iqtlabs CXX C)
enable_testing()

set(CMAKE_CXX_STANDARD 17)

# Install to PyBOMBS target prefix if defined
if(DEFINED ENV{PYBOMBS_PREFIX})
  set(CMAKE_INSTALL_PREFIX $ENV{PYBOMBS_PREFIX})
  message(
    STATUS
      "PyBOMBS installed GNU Radio. Setting CMAKE_INSTALL_PREFIX to $ENV{PYBOMBS_PREFIX}"
  )
endif()

# Select the release build type by default to get optimization flags
if(NOT CMAKE_BUILD_TYPE)
  set(CMAKE_BUILD_TYPE "Release")
  message(STATUS "Build type not specified: defaulting to release.")
endif(NOT CMAKE_BUILD_TYPE)
set(CMAKE_BUILD_TYPE
    ${CMAKE_BUILD_TYPE}
    CACHE STRING "")

# Make sure our local CMake Modules path comes first
list(INSERT CMAKE_MODULE_PATH 0 ${CMAKE_SOURCE_DIR}/cmake/Modules)
# Find gnuradio to get access to the cmake modules
find_package(Gnuradio "3.9" REQUIRED)

find_package(
  Boost ${Boost_Version}
  COMPONENTS filesystem iostreams
  REQUIRED)

find_package(OpenCV 4 REQUIRED)
include_directories(${CMAKE_SOURCE_DIR}/include ${OpenCV_INCLUDE_DIRS})

find_package(libsigmf REQUIRED)

find_package(Vulkan QUIET)
find_package(UHD QUIET)
if(Vulkan_FOUND)
  if(UHD_FOUND)
    set(VKFFT 1)
    message(INFO ": Vulkan and UHD found, vkfft will be built")
  else()
    message(INFO ": UHD NOT found, vkfft will NOT be built")
  endif()
else()
  message(INFO ": Vulkan NOT found, vkfft will NOT be built")
endif()

find_package(nlohmann_json 3.11.2 REQUIRED)

# Set the version information here
set(VERSION_MAJOR 1)
set(VERSION_API 0)
set(VERSION_ABI 0)
set(VERSION_PATCH 0)
execute_process(COMMAND bash -c "git describe --abbrev=0 --tags | cut -f 3 -d ." OUTPUT_VARIABLE VERSION_PATCH ERROR_VARIABLE VERSION_ERROR OUTPUT_STRIP_TRAILING_WHITESPACE)
if(VERSION_ERROR)
  message(WARNING "cannot determine git version")
endif()

cmake_policy(SET CMP0011 NEW)

# Enable generation of compile_commands.json for code completion engines
set(CMAKE_EXPORT_COMPILE_COMMANDS ON)

# ##############################################################################
# Minimum Version Requirements
# ##############################################################################

# include(GrMinReq)

# ##############################################################################
# Compiler settings
# ##############################################################################

# include(GrCompilerSettings)

# ##############################################################################
# Install directories
# ##############################################################################
include(GrVersion)

include(GrPlatform) # define LIB_SUFFIX

if(NOT CMAKE_MODULES_DIR)
  set(CMAKE_MODULES_DIR lib${LIB_SUFFIX}/cmake)
endif(NOT CMAKE_MODULES_DIR)

set(GR_INCLUDE_DIR include/gnuradio/iqtlabs)
set(GR_CMAKE_DIR ${CMAKE_MODULES_DIR}/gnuradio-iqtlabs)
set(GR_PKG_DATA_DIR ${GR_DATA_DIR}/${CMAKE_PROJECT_NAME})
set(GR_PKG_DOC_DIR ${GR_DOC_DIR}/${CMAKE_PROJECT_NAME})
set(GR_PKG_CONF_DIR ${GR_CONF_DIR}/${CMAKE_PROJECT_NAME}/conf.d)
set(GR_PKG_LIBEXEC_DIR ${GR_LIBEXEC_DIR}/${CMAKE_PROJECT_NAME})

# ##############################################################################
# On Apple only, set install name and use rpath correctly, if not already set
# ##############################################################################
if(APPLE)
  if(NOT CMAKE_INSTALL_NAME_DIR)
    set(CMAKE_INSTALL_NAME_DIR
        ${CMAKE_INSTALL_PREFIX}/${GR_LIBRARY_DIR}
        CACHE PATH "Library Install Name Destination Directory" FORCE)
  endif(NOT CMAKE_INSTALL_NAME_DIR)
  if(NOT CMAKE_INSTALL_RPATH)
    set(CMAKE_INSTALL_RPATH
        ${CMAKE_INSTALL_PREFIX}/${GR_LIBRARY_DIR}
        CACHE PATH "Library Install RPath" FORCE)
  endif(NOT CMAKE_INSTALL_RPATH)
  if(NOT CMAKE_BUILD_WITH_INSTALL_RPATH)
    set(CMAKE_BUILD_WITH_INSTALL_RPATH
        ON
        CACHE BOOL "Do Build Using Library Install RPath" FORCE)
  endif(NOT CMAKE_BUILD_WITH_INSTALL_RPATH)
endif(APPLE)

# ##############################################################################
# Find gnuradio build dependencies
# ##############################################################################
find_package(Doxygen)

# ##############################################################################
# Setup doxygen option
# ##############################################################################
if(DOXYGEN_FOUND)
  option(ENABLE_DOXYGEN "Build docs using Doxygen" ON)
else(DOXYGEN_FOUND)
  option(ENABLE_DOXYGEN "Build docs using Doxygen" OFF)
endif(DOXYGEN_FOUND)

# ##############################################################################
# Create uninstall target
# ##############################################################################
configure_file(${CMAKE_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in
               ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake @ONLY)

add_custom_target(uninstall ${CMAKE_COMMAND} -P
                            ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake)

# ##############################################################################
# Add subdirectories
# ##############################################################################
add_subdirectory(include/gnuradio/iqtlabs)
add_subdirectory(lib)
add_subdirectory(apps)
add_subdirectory(docs)
# NOTE: manually update below to use GRC to generate C++ flowgraphs w/o python
if(ENABLE_PYTHON)
  message(STATUS "PYTHON and GRC components are enabled")
  add_subdirectory(python/iqtlabs)
  add_subdirectory(grc)
else(ENABLE_PYTHON)
  message(STATUS "PYTHON and GRC components are disabled")
endif(ENABLE_PYTHON)

# ##############################################################################
# Install cmake search helper for this library
# ##############################################################################

install(FILES cmake/Modules/gnuradio-iqtlabsConfig.cmake
        DESTINATION ${GR_CMAKE_DIR})

include(CMakePackageConfigHelpers)
configure_package_config_file(
  ${PROJECT_SOURCE_DIR}/cmake/Modules/targetConfig.cmake.in
  ${CMAKE_CURRENT_BINARY_DIR}/cmake/Modules/${target}Config.cmake
  INSTALL_DESTINATION ${GR_CMAKE_DIR})