grammar.ebnf

//
// EBNF to be viewd at
//    (IPV6) https://www.bottlecaps.de/rr/ui
//    (IPV4) https://rr.red-dove.com/ui
//
// Copy and paste this at one of the urls shown above in the 'Edit Grammar' tab
// then click the 'View Diagram' tab.
//

MainProgram ::=
	( "#!" [^\n]* )? StatementList

StatementList ::=
	Statement+

Statement ::=
	StatementBody
	| "const" Identifier "=" Expression ";"
	| "var" Identifier ( "=" Expression )? ";"
	| "var" Identifier ":" parseArrayTyping ( "=" "[" ExpressionList "]" ) ";"
	| "import" ImportElementList ("from" readString)? ";"
	| "return" Expression ";"
	| "break" ";"
	| "continue" ";"
	| "delete" Expression ";"
	| "throw" Expression ";"
	| "try" StatementBody
		( "catch" "(" IdentifierList ")" StatementBody )?
		( "finally" ( "(" Identifier ")" )? StatementBody )
	| "function" Identifier "(" ArgumentDefinitionList ")" StatementBody
	| "struct" Identifier '{' parseStructElements '}' ";"
	| "switch" '(' Expression ')' '{' switchCaseElements '}'
	| "if" '(' Expression ')' StatementBody ( "else" StatementBody )?
	| "loop" StatementBody
	| "while" '(' Expression ')' StatementBody
	| "do" ScopelessStatementBody "while" '(' Expression ')' ";"
	| "for" '(' Statement Expression_opt ";" Expression ')' ScopelessStatementBody
	| "foreach" '(' IdentifierList "in" Expression ')' StatementBody
	| Expression ";"

StatementBody ::=
	ScopelessStatementBody

ScopelessStatementBody ::=
	'{' StatementList '}'

ImportElementList ::=
	ImportElement
	| ImportElementList ',' ImportElement

ImportElement ::=
	Identifier '*'? (':' NativeTypeName)? ("as" Identifier)?

ArgumentDefinitionList ::=
	/*empty*/
	| ArgumentDefinition
	| ArgumentDefinition ',' ArgumentDefinitionList 

ArgumentDefinition ::=
	'_'
	| Identifier "..."
	| Identifier ( ':' Typing )? ( '=' Expression )?

SimpleArgumentDefinitionList ::=
	/*empty*/
	| Identifier
	| Identifier ',' SimpleArgumentDefinitionList

parseTyping ::=
	':' BuiltinTypeName
	| ':' NativeTypeName
	| ':' NativeTypeName parseArrayTyping
	| ':' Identifier

parseFunctionBody ::=
	ScopelessStatementBody

parseStructElements ::=
	"static"? parseStructElement
	| parseStructElements "static"? parseStructElement

parseStructElement ::=
	"operator" '&' "this" '[' Identifier createParameterList parseOptionalTyping ']' ('=' Identifier createParameterList)?
	| "operator" '&' "this"  ArgumentDefinitionList
	| "sizeof" "this"
	| "foreach" '(' Identifier ',' Identifier ')' "in" "this" createParameterList
	| "cast" '<' ("int"|"float"|"string") '>' "this"
	| Identifier "in" "this" createParameterList parseFunctionBody
	| Identifier
	| "constructor" parseFunction
	| "destructor" parseFunction
	| ("private"|"public"|"internal") ("get"|"set")? Identifier

switchCaseElements ::=
	"default" ':' Statement
	| switchCaseElement
	| switchCaseElements switchCaseElement

switchCaseElement ::=
	"case" switchCaseExpression (',' switchCaseExpression)* ':' Statement

switchCaseExpression ::=
	Expression
	| Expression ".." Expression

var_assing_opt ::=
	'='	Expression

Expression_opt ::=
	/*empty*/
	| Expression

Expression ::=
	"(" Expression ")"
	| UnaryPrefixExpression
	| UnarySuffixExpression
	| BinaryExpression
	| BuiltinConstant
	| Expression "." Identifier
	| Expression "!" Typename "(" ExpressionList ")"
	| Expression "[" Expression "]"
	| Expression "?" Expression ":" Expression
	| "type" "<" BuiltinTypeName ">"
	| "typeof" Expression
	| "sizeof" "var"
	| "sizeof" NativeTypeName
	| "sizeof" Expression
	| "as" "<" NativeTypeName ">" Expression
	| "as" "<" Expression ">" Expression
	| "cast" "<" "int" ">" Expression
	| "cast" "<" "float" ">" Expression
	| "cast" "<" "string" ">" Expression
	| "new" Expression "(" ExpressionList ")"
	| "new_stack" Expression "(" ExpressionList ")"
	| "map" // TODO
	| "map_stack" // TODO
	| "function" // TODO
	| "(" argumentDefinition ")" "->" parseFunctionBody // TODO allow expressions
	| "$"
	| ['] . [']
	| ["] .* ["]
	| [`] .* [`]
	| Identifier
	| NumberConstant

UnaryPrefixExpression ::=
	"typeof" Expression
	| "++" Expression
	| "--" Expression
	| "!" Expression
	| "~" Expression
	| "&" Expression
	| "*" Expression
	| "+" Expression
	| "-" Expression

UnarySuffixExpression ::=
	Expression "++"
	| Expression "--"

BinaryExpression ::=
	Expression ">>" Expression
	| Expression ">>" Expression
	| Expression "<<" Expression
	| Expression "===" Expression
	| Expression "!==" Expression
	| Expression "==" Expression
	| Expression "!=" Expression
	| Expression "<=" Expression
	| Expression ">=" Expression
	| Expression "<" Expression
	| Expression ">" Expression
	| Expression "=" Expression
	| Expression "+=" Expression
	| Expression "-=" Expression
	| Expression "*=" Expression
	| Expression "/=" Expression
	| Expression "%=" Expression
	| Expression ">>=" Expression
	| Expression "<<=" Expression
	| Expression "&=" Expression
	| Expression "^=" Expression
	| Expression "|=" Expression
	| Expression "instanceof" Expression
	| Expression "in" Expression
	| Expression "||" Expression
	| Expression "^^" Expression
	| Expression "&&" Expression
	| Expression "|" Expression
	| Expression "^" Expression
	| Expression "&" Expression
	| Expression "+" Expression
	| Expression "-" Expression
	| Expression "*" Expression
	| Expression "/" Expression
	| Expression "%" Expression

BuiltinConstant ::=
	"true"
	| "false"
	| "null"
	| "undefined"
	| "NaN"
	| "Infinity"
	| "PI"
	| "E"

BuiltinTypeName ::=
	"undefined"
	| "int"
	| "float"
	| "pointer"
	| "struct"
	| "function"

NativeTypeName ::=
	"char"
	| "short"
	| "int"
	| "long"
	| "longlong"
	| "uchar"
	| "ushort"
	| "uint"
	| "ulong"
	| "ulonglong"
	| "i8"
	| "i16"
	| "i32"
	| "i64"
	| "u8"
	| "u16"
	| "u32"
	| "u64"
	| "float"
	| "double"
	| "f32"
	| "f64"
	| "cfunc"
	| "pointer"
	| "bool"
	| "ssize"
	| "size"
	| "intptr"
	| "uintptr"
	| "ptrdiff"
	| "var"

Identifier ::=
	[a-zA-Z_][a-zA-Z0-9_]*

NumberConstant ::=
	[-]?[0-9]+((e|.)[0-9]+)?

Comment ::=
	"//" .*
	| "/*" .*? "*/"