Codigo

[Ricklindo223]

Descrição do problema

A Raiz quadrada não está sendo executada normalmente, aparece que ela não foi declarada

Código

programa
{
  
    funcao inicio()
    {
        
        real num1, num2, menor, maior, cubo, raizq

        
        escreva("Digite o primeiro número: ")
        leia(num1)

        escreva("Digite o segundo número: ")
        leia(num2)

        
        se (num1 < num2)
        {
            menor = num1
            maior = num2
        }
        senao
        {
            menor = num2
            maior = num1
        }

        
        cubo = menor * menor * menor
        escreva("O cubo do menor número (", menor, ") é: ", cubo, "\n")

        
        se (maior >= 0)
        {
            raizQuadrada = raizq(maior)
            escreva("A raiz quadrada do maior número (", maior, ") é: ", raizQuadrada, "\n")
        }
        senao
        {
            escreva("Não é possível calcular a raiz quadrada de um número negativo (", maior, ")\n")
        }
    }
}

Comentários adicionais

No response

[lzfael]

Olá, Rick!

Encontrei uma solução para o seu problema que envolve o cálculo da raiz quadrada de um número em Portugol. O problema original era a utilização de uma função inexistente para calcular a raiz quadrada. No Portugol, encontrei uma maneira de resolver isso utilizando a biblioteca Matemática e sua função mat.raiz().

Aqui está o código resolvido:

programa
{   
    inclua biblioteca Matematica --> mat
    funcao inicio()
    {   
        real num1, num2, menor, maior, cubo, raizQuadrada

        escreva("Digite o primeiro número: ")
        leia(num1)

        escreva("Digite o segundo número: ")
        leia(num2)

        se (num1 < num2)
        {
            menor = num1
            maior = num2
        }
        senao
        {
            menor = num2
            maior = num1
        }

        cubo = menor * menor * menor
        escreva("O cubo do menor número (", menor, ") é: ", cubo, "\n")

        se (maior >= 0)
        {
            raizQuadrada = mat.raiz(maior, 2.0)  // Usando a função 'mat.raiz()' da biblioteca Matematica
            escreva("A raiz quadrada do maior número (", maior, ") é: ", raizQuadrada, "\n")
        }
        senao
        {
            escreva("Não é possível calcular a raiz quadrada de um número negativo (", maior, ")\n")
        }
    }
}

Espero ter te ajudado!