New SRTP Aliases constraints giving "Invalid constraint."

[TheAngryByrd]

👋 F# 7 introduced new ways of working with SRTP aliases however I've ran into an issue converting some type contraints.

Below is some code from IcedTask that uses this feature to create the Awaiter/Awaitable structures with SRTP aliases.

In the FooBuilder I show what I think are two implementations that should result in the same behavior but they're not.

---

open System.Runtime.CompilerServices

/// A structure that looks like an Awaiter
type Awaiter<'Awaiter, 'TResult
    when 'Awaiter :> ICriticalNotifyCompletion
    and 'Awaiter: (member get_IsCompleted: unit -> bool)
    and 'Awaiter: (member GetResult: unit -> 'TResult)> = 'Awaiter

/// Functions for Awaiters
type Awaiter =
    /// Gets a value that indicates whether the asynchronous task has completed
    static member inline IsCompleted<'Awaiter, 'TResult when Awaiter<'Awaiter, 'TResult>>
        (awaiter: 'Awaiter)
        =
        awaiter.get_IsCompleted ()

    /// Ends the wait for the completion of the asynchronous task.
    static member inline GetResult<'Awaiter, 'TResult when Awaiter<'Awaiter, 'TResult>>
        (awaiter: 'Awaiter)
        =
        awaiter.GetResult()


    /// Schedules the continuation action that's invoked when the instance completes
    static member inline OnCompleted<'Awaiter, 'TResult, 'Continuation
        when Awaiter<'Awaiter, 'TResult>>
        (
            awaiter: 'Awaiter,
            continuation: System.Action
        ) =
        awaiter.OnCompleted(continuation)

    /// Schedules the continuation action that's invoked when the instance completes.
    static member inline UnsafeOnCompleted<'Awaiter, 'TResult, 'Continuation
        when Awaiter<'Awaiter, 'TResult>>
        (
            awaiter: 'Awaiter,
            continuation: System.Action
        ) =
        awaiter.UnsafeOnCompleted(continuation)

/// A structure looks like an Awaitable
type Awaitable<'Awaitable, 'Awaiter, 'TResult
    when 'Awaitable: (member GetAwaiter: unit -> Awaiter<'Awaiter, 'TResult>)> = 'Awaitable

/// Functions for Awaitables
type Awaitable =
    /// Creates an awaiter for this value.
    static member inline GetAwaiter<'Awaitable, 'Awaiter, 'TResult
        when Awaitable<'Awaitable, 'Awaiter, 'TResult>>
        (awaitable: 'Awaitable)
        =
        awaitable.GetAwaiter()

open Microsoft.FSharp.Core.CompilerServices
open System.Threading

type FooBuilder() =

    // Compiles
    [<NoEagerConstraintApplication>]
    member inline _.Source<'Awaitable, 'Awaiter, 'TResult1, 'Error
        when ^Awaitable: (member GetAwaiter: unit -> ^Awaiter)
        and ^Awaiter :> ICriticalNotifyCompletion
        and ^Awaiter: (member get_IsCompleted: unit -> bool)
        and ^Awaiter: (member GetResult: unit -> Result<'TResult1, 'Error>)>

        (task: 'Awaitable)
        : CancellationToken -> ^Awaiter =
        (fun (ct: CancellationToken) -> Awaitable.GetAwaiter task)


    // Doesn't
    // Invalid constraint. Valid constraint forms include "'T :> ISomeInterface" for interface constraints and "SomeConstrainingType<'T>" for self-constraints. See https://aka.ms/fsharp-type-constraints.F# Compiler3533
    [<NoEagerConstraintApplication>]
    member inline _.Source<'Awaitable, 'Awaiter, 'TResult1, 'Error
        when Awaitable<'Awaitable, 'Awaiter, Result<'TResult1, 'Error>>>

        (task: 'Awaitable)
        : CancellationToken -> ^Awaiter =
        (fun (ct: CancellationToken) -> Awaitable.GetAwaiter task)

---

What am I doing wrong here or is this maybe a bug or maybe a refinement needed?

[En3Tho]

Is it supposed to work with multiple generic parameters like this? Does when 'Awaitble :> Awaitable<'Awaitable, ...> work?

[vzarytovskii]

Like

[<NoEagerConstraintApplication>]
member inline _.Source<'Awaitable, 'Awaiter, 'TResult1, 'Error when Awaitable<'Awaitable, 'Awaiter ,'Result> and 'Result :> Result<'TResult1, 'Error>> (task: 'Awaitable) : CancellationToken -> ^Awaiter =
    (fun (ct: CancellationToken) -> Awaitable.GetAwaiter task)

[vzarytovskii]

On the second thought, that probably won't work.

[TheAngryByrd]

@vzarytovskii you're on vacation, stop it!

[En3Tho]

I seem to get more errors with this:

I guess you have Treat warnings as errors option on? It works on my machine, just produces warnings you've described (and I'm not sure what is the point of producing those, really)

[TheAngryByrd]

Yeah you're right I have WarnAsError on, however taking that off doesn't solve the issue as eventually I get this:

This construct causes code to be less generic than indicated by the type annotations. The type variable 'TaskLike has been constrained to be type 'obj'.F# Compiler[64](https://docs.microsoft.com/en-us/dotnet/fsharp/language-reference/compiler-messages/fs0064)