Is there possible to write a one file runnable crystal to try reproduce possible bug in avram?

[zw963]

e.g. just like this: (although, following code actually not work)

class CreateFoo::V20240420041990 < Avram::Migrator::Migration::V1
  def migrate
    create table_for(Foo), if_not_exists: true do
      primary_key id : Int64
      add is_211 : Bool, index: true, default: false
    end
  end

  def rollback
    drop table_for(Foo)
  end
end

Avram::Migrator::Runner.migrations << CreateFoo::V20240420041990

class Foo < BaseModel
  table do
    column is_211 : Bool
  end
end

Avram::Migrator::Runner.new.run_pending_migrations

class FooQuery < University::BaseQuery
end

# insert records, we can saw those bool record save to db as `t` and `f'.

FooQuery.new.is_211(true)            # => the result always empty.
pp! FooQuery.new.is_211(true).to_sql # ["SELECT * FROM foo WHERE universities.is_211 = $1", "true"]

[jwoertink]

Not tested, but you can try this

require "pg"
require "avram"

class AppDatabase < Avram::Database
end

AppDatabase.configure do |settings|
  settings.credentials = Avram::Credentials.new(database: "test_db", username: "postgres", hostname: "localhost")
end

Avram.configure do |settings|
  settings.database_to_migrate = AppDatabase
  settings.lazy_load_enabled = true
end

class CreateFoo::V20240420041990 < Avram::Migrator::Migration::V1
  def migrate
    create table_for(Foo), if_not_exists: true do
      primary_key id : Int64
      add is_211 : Bool, index: true, default: false
    end
  end

  def rollback
    drop table_for(Foo)
  end
end

Avram::Migrator::Runner.new.run_next_migration

class Foo < BaseModel
  table do
    column is_211 : Bool
  end
end

Foo::SaveOperation.create!(is_211: true)

Foo::BaseQuery.new.is_211(true).select_count #=> 1

No need for lucky exec here. You can just make a Crystal file and run it directly.

[zw963]

Thank you, following code is working.

# NOTICE: It drop db, and recreate it, so, be careful to not loss your's data.

require "pg"
require "avram"

class AppDatabase < Avram::Database
end

AppDatabase.configure do |settings|
  settings.credentials = Avram::Credentials.new(database: "test_db", username: "postgres", hostname: "localhost")
end

Avram.configure do |settings|
  settings.database_to_migrate = AppDatabase
  settings.lazy_load_enabled = true
end

class CreateFoo::V20240420041990 < Avram::Migrator::Migration::V1
  def migrate
    create table_for(Foo), if_not_exists: true do
      primary_key id : Int64
      add is_211 : Bool, index: true, default: false
      add_timestamps
    end
  end

  def rollback
    drop table_for(Foo)
  end
end

Avram::Migrator::Runner.drop_db(true)
Avram::Migrator::Runner.create_db(true)
Avram::Migrator::Runner.new.run_next_migration

abstract class BaseModel < Avram::Model
  def self.database : Avram::Database.class
    AppDatabase
  end
end

class Foo < BaseModel
  table do
    column is_211 : Bool
  end
end

Foo::SaveOperation.create!(is_211: true)

pp! Foo::BaseQuery.new.is_211(true).select_count # => 1

But, one concerns, we have to add add_timestamps when create table, otherwise, it raise exception when
create!, please check following backtrace.

 ╰─ $ cr run 1.cr
Migrated CreateFoo::V20240420041990
Unhandled exception: column "created_at" of relation "foos" does not exist (PQ::PQError)
  from lib/pg/src/pq/connection.cr:214:7 in 'handle_error'
  from lib/pg/src/pq/connection.cr:197:7 in 'handle_async_frames'
  from lib/pg/src/pq/connection.cr:173:7 in 'read'
  from lib/pg/src/pq/connection.cr:168:7 in 'read'
  from lib/pg/src/pq/connection.cr:446:31 in 'expect_frame'
  from lib/pg/src/pq/connection.cr:445:5 in 'expect_frame'
  from lib/pg/src/pg/statement.cr:18:5 in 'perform_query'
  from lib/db/src/db/statement.cr:101:9 in 'perform_query_with_rescue'
  from lib/db/src/db/statement.cr:88:7 in 'query:args'
  from lib/db/src/db/query_methods.cr:46:7 in 'query:args'
  from lib/db/src/db/query_methods.cr:61:12 in 'insert'
  from lib/avram/src/avram/save_operation.cr:271:7 in 'insert_or_update'
  from lib/avram/src/avram/save_operation.cr:217:9 in 'save'
  from lib/avram/src/avram/save_operation.cr:243:8 in 'save!'
  from 1.cr:41:3 in 'create!:is_211'
  from 1.cr:48:1 in '__crystal_main'
  from /home/zw963/Crystal/share/crystal/src/crystal/main.cr:129:5 in 'main_user_code'
  from /home/zw963/Crystal/share/crystal/src/crystal/main.cr:115:7 in 'main'
  from /home/zw963/Crystal/share/crystal/src/crystal/main.cr:141:3 in 'main'
  from /usr/lib/libc.so.6 in '??'
  from /usr/lib/libc.so.6 in '__libc_start_main'
  from /home/zw963/.cache/crystal/crystal-run-1.tmp in '_start'
  from ???

[jwoertink]

Sorry, I forgot. If you don't specify primary_key or add_timestamps, then your model needs skip_default_columns

class CreateFoo::V20240420041990 < Avram::Migrator::Migration::V1
  def migrate
    create table_for(Foo), if_not_exists: true do
      add is_211 : Bool, index: true, default: false
    end
  end

  def rollback
    drop table_for(Foo)
  end
end

class Foo < BaseModel
  skip_default_columns
  table do
    column is_211 : Bool
  end
end