build.gradle

import org.apache.tools.ant.util.TeeOutputStream

plugins {
    id 'java'
    id 'jacoco'
    id 'org.sonarqube' version '5.0.0.4638'
}

sonar {
    properties {
        property 'sonar.projectKey', 'nicktindall_java-raft'
        property 'sonar.organization', 'nicktindall'
        property 'sonar.host.url', 'https://sonarcloud.io'
        property 'sonar.login', '74ce1c65bd9ae5f476d0cb81a500d371680fe7c6'
    }
}

jacoco {
    toolVersion = '0.8.9'
}

jacocoTestReport {
    reports {
        xml.required.set(true)
    }
}

java {
    toolchain {
        languageVersion.set(JavaLanguageVersion.of(17))
    }
}

group 'id.au.tindall.distalg'
version '1.0-SNAPSHOT'

repositories {
    mavenCentral()
}

def mockitoVersion = '5.5.0'
def log4jVersion = '2.20.0'

dependencies {
    implementation group: 'org.apache.logging.log4j', name: 'log4j-api', version: log4jVersion
    testImplementation group: 'org.apache.logging.log4j', name: 'log4j-core', version: log4jVersion
    testImplementation group: 'org.mockito', name: 'mockito-core', version: mockitoVersion
    testImplementation group: 'org.mockito', name: 'mockito-junit-jupiter', version: mockitoVersion
    testImplementation group: 'org.assertj', name: 'assertj-core', version: '3.24.2'
    testImplementation 'org.awaitility:awaitility:4.2.0'
    testImplementation 'org.junit.jupiter:junit-jupiter:5.10.0'
    testImplementation group: 'org.junit.platform', name: 'junit-platform-launcher', version: '1.10.0'
}

test {
    useJUnitPlatform()
}

// Repeat the LiveServerTest (long run) until failure
task longRunTest(type: JavaExec) {
    doFirst {
        standardOutput = new TeeOutputStream(
                new FileOutputStream("longRunTest.out.txt"), System.out);
    }
    dependsOn classes
    jvmArgs("-XX:+HeapDumpOnOutOfMemoryError", "-XX:+FlightRecorder", "-XX:StartFlightRecording=disk=true,maxsize=128MB,filename=" + project.projectDir + "/longRunTest.jfr", "-Xlog:jfr=debug")
    systemProperties("LiveServerTest.longRun": "true")
    workingDir = file(buildDir)
    classpath = sourceSets.test.runtimeClasspath
    main = "au.id.tindall.distalg.raft.LiveServerTest"
}