Add json format functions for key-value lists

lib/stdlib/src/json.erl

@@ -51,7 +51,9 @@ standards. The decoder is tested using [JSONTestSuite](https://github.com/nst/JS
 
 -export([
          format/1, format/2, format/3,
-         format_value/3
+         format_value/3,
+         format_key_value_list/3,
+         format_key_value_list_checked/3
         ]).
 -export_type([formatter/0]).
 
@@ -694,6 +696,14 @@ format_tail([Head|Tail], Enc, State, IndentAll, IndentRow) ->
 format_tail([], _, _, _, _) ->
     [].
 
+-doc """
+Format function for lists of key-value pairs as JSON objects.
+
+Accepts lists with atom, binary, integer, or float keys.
+""".
+-doc(#{since => <<"OTP 27.2">>}).
+
+-spec format_key_value_list([{term(), term()}], Encode::formatter(), State::map()) -> iodata().
 format_key_value_list(KVList, UserEnc, #{level := Level} = State) ->
     {_,Indent} = indent(State),
     NextState = State#{level := Level+1},
@@ -706,6 +716,48 @@ format_key_value_list(KVList, UserEnc, #{level := Level} = State) ->
             end,
     format_object([Entry(Key,Value) || {Key, Value} <- KVList], Indent).
 
+-doc """
+Format function for lists of key-value pairs as JSON objects.
+
+Accepts lists with atom, binary, integer, or float keys.
+Verifies that no duplicate keys will be produced in the
+resulting JSON object.
+
+## Errors
+
+Raises `error({duplicate_key, Key})` if there are duplicates.
+""".
+-doc(#{since => <<"OTP 27.2">>}).
+
+-spec format_key_value_list_checked([{term(), term()}], Encoder::formatter(), State::map()) -> iodata().
+format_key_value_list_checked(KVList, UserEnc, State) when is_function(UserEnc, 3) ->
+    {_,Indent} = indent(State),
+    format_object(do_format_checked(KVList, UserEnc, State), Indent).
+
+do_format_checked([], _, _) ->
+    [];
+
+do_format_checked(KVList, UserEnc,  #{level := Level} = State) ->
+    NextState = State#{level := Level + 1},
+    {KISize, KeyIndent} = indent(NextState),
+    EncKeyFun = fun(KeyVal, _Fun) -> UserEnc(KeyVal, UserEnc, NextState) end,
+    EncListFun =
+        fun({Key, Value}, {Acc, Visited0}) ->
+                EncKey = iolist_to_binary(key(Key, EncKeyFun)),
+                case is_map_key(EncKey, Visited0) of
+                    true ->
+                        error({duplicate_key, Key});
+                    false ->
+                        Visited1 = Visited0#{EncKey => true},
+                        ValState = NextState#{col := KISize + 2 + erlang:iolist_size(EncKey)},
+                        EncEntry = [$, , KeyIndent, EncKey, ": "
+                                   | UserEnc(Value, UserEnc, ValState)],
+                        {[EncEntry | Acc], Visited1}
+                end
+        end,
+    {EncKVList, _} = lists:foldl(EncListFun, {[], #{}}, KVList),
+    lists:reverse(EncKVList).
+
 format_object([], _) -> <<"{}">>;
 format_object([[_Comma,KeyIndent|Entry]], Indent) ->
     [_Key,_Colon|Value] = Entry,

lib/stdlib/test/json_SUITE.erl

@@ -39,6 +39,7 @@
     test_encode_proplist/1,
     test_encode_escape_all/1,
     test_format_list/1,
+    test_format_proplist/1,
     test_format_map/1,
     test_format_fun/1,
     test_decode_atoms/1,
@@ -91,6 +92,7 @@ groups() ->
         ]},
         {format, [parallel], [
             test_format_list,
+            test_format_proplist,
             test_format_map,
             test_format_fun
         ]},
@@ -367,6 +369,37 @@ test_format_list(_Config) ->
     ?assertEqual(ListString, format([~"foo", ~"bar", ~"baz"], #{indent => 3})),
     ok.
 
+test_format_proplist(_Config) ->
+    Formatter = fun({kvlist, KVList}, Fun, State) ->
+                        json:format_key_value_list(KVList, Fun, State);
+                   ({kvlist_checked, KVList}, Fun, State) ->
+                        json:format_key_value_list_checked(KVList, Fun, State);
+                   (Other, Fun, State) ->
+                        json:format_value(Other, Fun, State)
+                end,
+
+    ?assertEqual(~"""
+                  {
+                    "a": 1,
+                    "b": "str"
+                  }
+
+                  """, format({kvlist, [{a, 1}, {b, ~"str"}]}, Formatter)),
+
+    ?assertEqual(~"""
+                  {
+                    "a": 1,
+                    "b": "str"
+                  }
+
+                  """, format({kvlist_checked, [{a, 1}, {b, ~"str"}]}, Formatter)),
+
+
+    ?assertError({duplicate_key, a},
+                 format({kvlist_checked, [{a, 1}, {b, ~"str"}, {a, 2}]}, Formatter)),
+
+    ok.
+
 test_format_map(_Config) ->
     ?assertEqual(~'{}\n', format(#{})),
     ?assertEqual(~'{ "key": "val" }\n', format(#{key => val})),