Prepare release 0.7

3rdparty/CMakeLists.txt

@@ -0,0 +1,145 @@
+cmake_minimum_required(VERSION 2.8.11)
+
+project(3rdparty)
+
+include(ExternalProject)
+
+if(WIN32)
+	ExternalProject_Add(
+		patch
+		URL https://downloads.sourceforge.net/project/gnuwin32/patch/2.5.9-7/patch-2.5.9-7-bin.zip
+		#URL ${CMAKE_CURRENT_SOURCE_DIR}/patch-2.5.9-7-bin.zip
+		URL_MD5 b9c8b31d62f4b2e4f1887bbb63e8a905
+		CONFIGURE_COMMAND ""
+		BUILD_COMMAND ""
+		INSTALL_COMMAND
+		${CMAKE_COMMAND} -E copy <SOURCE_DIR>/bin/patch.exe ${CMAKE_CURRENT_BINARY_DIR}/patch.exe &&
+		${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/patch.exe.manifest ${CMAKE_CURRENT_BINARY_DIR}/patch.exe.manifest
+	)
+	set(PATCH_EXECUTABLE ${CMAKE_CURRENT_BINARY_DIR}/patch.exe)
+else()
+	ExternalProject_Add(
+		patch
+		SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR}
+		CONFIGURE_COMMAND ""
+		BUILD_COMMAND ""
+		INSTALL_COMMAND ""
+	)
+	set(PATCH_EXECUTABLE patch)
+endif()
+
+add_subdirectory(atidaq)
+add_subdirectory(boost)
+add_subdirectory(bullet)
+add_subdirectory(eigen)
+add_subdirectory(libiconv)
+add_subdirectory(nlopt)
+add_subdirectory(ode)
+add_subdirectory(pqp)
+add_subdirectory(simage)
+add_subdirectory(solid)
+add_subdirectory(zlib)
+
+add_subdirectory(libxml2)
+add_subdirectory(coin)
+
+add_subdirectory(libxslt)
+add_subdirectory(soqt)
+
+set(
+	CPACK_INSTALL_CMAKE_PROJECTS
+	"${CMAKE_CURRENT_BINARY_DIR}/atidaq/atidaq-prefix/src/atidaq-build;atidaq;ALL;/"
+	"${CMAKE_CURRENT_BINARY_DIR}/bullet/bullet-prefix/src/bullet-build;bullet;ALL;/"
+	"${CMAKE_CURRENT_BINARY_DIR}/coin/coin-prefix/src/coin-build;coin;ALL;/"
+	"${CMAKE_CURRENT_BINARY_DIR}/eigen/eigen-prefix/src/eigen-build;eigen;ALL;/"
+	"${CMAKE_CURRENT_BINARY_DIR}/libiconv/libiconv-prefix/src/libiconv-build;libiconv;ALL;/"
+	"${CMAKE_CURRENT_BINARY_DIR}/libxml2/libxml2-prefix/src/libxml2-build;libxml2;ALL;/"
+	"${CMAKE_CURRENT_BINARY_DIR}/libxslt/libxslt-prefix/src/libxslt-build;libxslt;ALL;/"
+	"${CMAKE_CURRENT_BINARY_DIR}/nlopt/nlopt-prefix/src/nlopt-build;nlopt;ALL;/"
+	"${CMAKE_CURRENT_BINARY_DIR}/ode/ode-prefix/src/ode-build;ode;ALL;/"
+	"${CMAKE_CURRENT_BINARY_DIR}/pqp/pqp-prefix/src/pqp-build;pqp;ALL;/"
+	"${CMAKE_CURRENT_BINARY_DIR}/simage/simage-prefix/src/simage-build;simage;ALL;/"
+	"${CMAKE_CURRENT_BINARY_DIR}/solid/solid-prefix/src/solid-build;solid;ALL;/"
+	"${CMAKE_CURRENT_BINARY_DIR}/soqt/soqt-prefix/src/soqt-build;soqt;ALL;/"
+	"${CMAKE_CURRENT_BINARY_DIR}/zlib/zlib-prefix/src/zlib-build;zlib;ALL;/"
+)
+
+set(
+	CPACK_INSTALLED_DIRECTORIES
+	${CMAKE_CURRENT_BINARY_DIR}/boost/boost-prefix/src/boost/boost ${CMAKE_INSTALL_INCLUDEDIR}/boost
+)
+
+set(CPACK_PACKAGE_VERSION_MAJOR 0)
+set(CPACK_PACKAGE_VERSION_MINOR 7)
+set(CPACK_PACKAGE_VERSION_PATCH 0)
+
+set(CPACK_PACKAGE_VERSION ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH})
+
+if(MSVC)
+	if(CMAKE_CXX_COMPILER_VERSION MATCHES "^([0-9]+)\\.([0-9])([0-9]*)\\.([0-9]+)\\.")
+		if(CMAKE_CXX_COMPILER_VERSION VERSION_GREATER 18)
+			math(EXPR LINKER_VERSION_MAJOR "${CMAKE_MATCH_1} - 5")
+		else()
+			math(EXPR LINKER_VERSION_MAJOR "${CMAKE_MATCH_1} - 6")
+		endif()
+		set(PLATFORM_TOOLSET_MAJOR ${LINKER_VERSION_MAJOR})
+		set(PLATFORM_TOOLSET_MINOR ${CMAKE_MATCH_2})
+		set(LINKER_VERSION "${LINKER_VERSION_MAJOR}.${CMAKE_MATCH_2}${CMAKE_MATCH_3}.${CMAKE_MATCH_4}")
+	endif()
+	if(CMAKE_CL_64)
+		set(CPACK_PACKAGE_FILE_NAME "rl-3rdparty-${CPACK_PACKAGE_VERSION}-msvc-${PLATFORM_TOOLSET_MAJOR}.${PLATFORM_TOOLSET_MINOR}-x64")
+		set(CPACK_PACKAGE_INSTALL_DIRECTORY "Robotics Library\\\\${CPACK_PACKAGE_VERSION}\\\\MSVC\\\\${PLATFORM_TOOLSET_MAJOR}.${PLATFORM_TOOLSET_MINOR}\\\\x64")
+		set(CPACK_PACKAGE_NAME "Robotics Library ${CPACK_PACKAGE_VERSION} Third-Party Dependencies - MSVC ${PLATFORM_TOOLSET_MAJOR}.${PLATFORM_TOOLSET_MINOR} (x64)")
+	else()
+		set(CPACK_PACKAGE_FILE_NAME "rl-3rdparty-${CPACK_PACKAGE_VERSION}-msvc-${PLATFORM_TOOLSET_MAJOR}.${PLATFORM_TOOLSET_MINOR}-x86")
+		set(CPACK_PACKAGE_INSTALL_DIRECTORY "Robotics Library\\\\${CPACK_PACKAGE_VERSION}\\\\MSVC\\\\${PLATFORM_TOOLSET_MAJOR}.${PLATFORM_TOOLSET_MINOR}\\\\x86")
+		set(CPACK_PACKAGE_NAME "Robotics Library ${CPACK_PACKAGE_VERSION} Third-Party Dependencies - MSVC ${PLATFORM_TOOLSET_MAJOR}.${PLATFORM_TOOLSET_MINOR} (x86)")
+	endif()
+else()
+	set(CPACK_PACKAGE_FILE_NAME "rl-3rdparty-${CPACK_PACKAGE_VERSION}-${CMAKE_SYSTEM_NAME}")
+	set(CPACK_PACKAGE_INSTALL_DIRECTORY "rl-${CPACK_PACKAGE_VERSION}")
+	set(CPACK_PACKAGE_NAME "Robotics Library ${CPACK_PACKAGE_VERSION} Third-Party Dependencies")
+endif()
+
+set(CPACK_DEBIAN_PACKAGE_HOMEPAGE "https://www.roboticslibrary.org/contact")
+set(CPACK_DEBIAN_PACKAGE_NAME "librl-3rdparty")
+set(CPACK_DEBIAN_PACKAGE_SECTION "devel")
+set(CPACK_NSIS_DISPLAY_NAME ${CPACK_PACKAGE_NAME})
+set(CPACK_NSIS_EXECUTABLES_DIRECTORY ${CMAKE_INSTALL_BINDIR})
+set(CPACK_NSIS_HELP_LINK "https://www.roboticslibrary.org/contact")
+set(CPACK_NSIS_INSTALLED_ICON_NAME Uninstall.exe)
+set(CPACK_NSIS_MODIFY_PATH ON)
+set(CPACK_NSIS_MUI_ICON ${CMAKE_CURRENT_SOURCE_DIR}/../robotics-library.ico)
+set(CPACK_NSIS_MUI_UNIICON ${CMAKE_CURRENT_SOURCE_DIR}/../robotics-library.ico)
+set(CPACK_NSIS_PACKAGE_NAME ${CPACK_PACKAGE_NAME})
+set(CPACK_NSIS_URL_INFO_ABOUT "https://www.roboticslibrary.org/contact")
+set(CPACK_PACKAGE_CONTACT "Robotics Library Team <[email protected]>")
+set(CPACK_PACKAGE_VENDOR "Robotics Library")
+set(CPACK_PROJECT_CONFIG_FILE ${CMAKE_CURRENT_SOURCE_DIR}/CPackProjectConfig.cmake)
+set(CPACK_RPM_PACKAGE_GROUP "Development/Libraries")
+set(CPACK_RPM_PACKAGE_NAME "rl-3rdparty")
+set(CPACK_RPM_PACKAGE_SUMMARY "Robotics Library Third-Party Dependencies")
+set(CPACK_RPM_PACKAGE_URL "https://www.roboticslibrary.org/contact")
+set(CPACK_WIX_EXTENSIONS "WiXUtilExtension")
+set(
+	CPACK_WIX_EXTRA_SOURCES
+	${CMAKE_CURRENT_BINARY_DIR}/WixExtra.wxs
+	${CMAKE_CURRENT_SOURCE_DIR}/../cmake/WixUI_FeatureTreeNoLicense.wxs
+)
+set(CPACK_WIX_PATCH_FILE ${CMAKE_CURRENT_BINARY_DIR}/WixPatch.xml)
+set(CPACK_WIX_PRODUCT_ICON ${CMAKE_CURRENT_SOURCE_DIR}/../robotics-library.ico)
+set(CPACK_WIX_PROGRAM_MENU_FOLDER ${CPACK_PACKAGE_NAME})
+set(CPACK_WIX_PROPERTY_ARPHELPLINK "https://www.roboticslibrary.org/contact")
+set(CPACK_WIX_PROPERTY_ARPURLINFOABOUT "https://www.roboticslibrary.org/")
+set(CPACK_WIX_ROOT_FEATURE_TITLE "Robotics Library Third-Party Dependencies")
+set(CPACK_WIX_UI_BANNER ${CMAKE_CURRENT_SOURCE_DIR}/../cmake/WixUIBanner.bmp)
+set(CPACK_WIX_UI_DIALOG ${CMAKE_CURRENT_SOURCE_DIR}/../cmake/WixUIDialog.bmp)
+set(CPACK_WIX_UI_REF "WixUI_FeatureTreeNoLicense")
+
+configure_file(../cmake/WixExtra.wxs.in ${CMAKE_CURRENT_BINARY_DIR}/WixExtra.wxs)
+configure_file(../cmake/WixPatch.xml.in ${CMAKE_CURRENT_BINARY_DIR}/WixPatch.xml)
+
+set(CMAKE_INSTALL_SYSTEM_RUNTIME_COMPONENT system)
+include(InstallRequiredSystemLibraries)
+
+include(CPack)

3rdparty/atidaq/CMakeLists.txt

@@ -0,0 +1,23 @@
+cmake_minimum_required(VERSION 2.8.11)
+
+project(atidaq)
+
+include(ExternalProject)
+
+if(NOT WIN32)
+	set(PATCH_BINARY "--binary")
+endif()
+
+ExternalProject_Add(
+	atidaq
+	DEPENDS patch
+	URL http://www.ati-ia.com/library/software/daq_ft/ATIDAQ%20C%20Library.zip
+	#URL ${CMAKE_CURRENT_SOURCE_DIR}/ATIDAQ%20C%20Library.zip
+	URL_MD5 02c26650792927a09202196c574522cd
+	PATCH_COMMAND
+	${PATCH_EXECUTABLE} -p1 -t -N ${PATCH_BINARY} < ${CMAKE_CURRENT_SOURCE_DIR}/atidaq.patch &&
+	${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/atidaq-config.cmake.in <SOURCE_DIR>/atidaq-config.cmake.in &&
+	${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/CMakeLists.txt.in <SOURCE_DIR>/CMakeLists.txt
+	CMAKE_ARGS -DCMAKE_BUILD_TYPE=${CMAKE_BUILD_TYPE} -DCMAKE_CFG_INTDIR=${CMAKE_CFG_INTDIR} -DCMAKE_INSTALL_PREFIX=${CMAKE_INSTALL_PREFIX} -DCMAKE_PREFIX_PATH=${CMAKE_PREFIX_PATH} -DCMAKE_TRY_COMPILE_CONFIGURATION=${CMAKE_TRY_COMPILE_CONFIGURATION}
+	INSTALL_DIR ${CMAKE_INSTALL_PREFIX}
+)

3rdparty/atidaq/CMakeLists.txt.in

@@ -0,0 +1,183 @@
+cmake_minimum_required(VERSION 2.8.11)
+
+project(atidaq)
+
+include(CMakePackageConfigHelpers)
+include(GNUInstallDirs)
+
+set(VERSION_MAJOR 1)
+set(VERSION_MINOR 0)
+set(VERSION_PATCH 7)
+set(VERSION ${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_PATCH})
+
+if(WIN32)
+	set(BUILD_SHARED_LIBS OFF)
+else()
+	option(BUILD_SHARED_LIBS "Build shared libraries" ON)
+endif()
+
+set(
+	HDRS
+	ATIDAQ/ascii.h
+	ATIDAQ/asciitab.h
+	ATIDAQ/dom.h
+	ATIDAQ/ftconfig.h
+	ATIDAQ/ftrt.h
+	ATIDAQ/ftsharedrt.h
+	ATIDAQ/iasciitab.h
+	ATIDAQ/latin1tab.h
+	ATIDAQ/nametab.h
+	ATIDAQ/stack.h
+	ATIDAQ/utf8tab.h
+	ATIDAQ/xmldef.h
+	ATIDAQ/xmlparse.h
+	ATIDAQ/xmlrole.h
+	ATIDAQ/xmltok.h
+	ATIDAQ/xmltok_impl.h
+)
+
+set(
+	SRCS
+	ATIDAQ/dom.c
+	ATIDAQ/expatls.c
+	ATIDAQ/ftconfig.c
+	ATIDAQ/ftrt.c
+	ATIDAQ/node.c
+	ATIDAQ/stack.c
+	ATIDAQ/xmlparse.c
+	ATIDAQ/xmlrole.c
+	ATIDAQ/xmltok.c
+)
+
+add_library(atidaq ${HDRS} ${SRCS})
+
+target_include_directories(
+	atidaq
+	INTERFACE
+	$<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}/ATIDAQ>
+	$<INSTALL_INTERFACE:$<INSTALL_PREFIX>/${CMAKE_INSTALL_INCLUDEDIR}>
+)
+
+if(UNIX)
+	target_link_libraries(atidaq m)
+endif()
+
+set_target_properties(atidaq PROPERTIES DEBUG_POSTFIX d VERSION ${VERSION})
+
+install(FILES ${HDRS} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/atidaq COMPONENT development)
+
+install(
+	TARGETS	atidaq
+	EXPORT atidaq
+	ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR} COMPONENT development
+	LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR} COMPONENT runtime NAMELINK_SKIP
+	RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT runtime
+)
+
+if(BUILD_SHARED_LIBS)
+	install(
+		TARGETS	atidaq
+		EXPORT atidaq
+		LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR} COMPONENT development NAMELINK_ONLY
+	)
+endif()
+
+if(MSVC AND BUILD_SHARED_LIBS AND ${CMAKE_MAJOR_VERSION} GREATER 2 AND ${CMAKE_MINOR_VERSION} GREATER 0)
+	install(FILES $<TARGET_PDB_FILE:atidaq> DESTINATION ${CMAKE_INSTALL_BINDIR} CONFIGURATIONS Debug RelWithDebInfo COMPONENT debug)
+endif()
+
+add_executable(calinfo Samples/calinfo.c)
+target_link_libraries(calinfo atidaq)
+
+install(
+	TARGETS	calinfo
+	COMPONENT programs
+	ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
+	LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
+	RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
+)
+
+add_executable(ftconvert Samples/ftconvert.c)
+target_link_libraries(ftconvert atidaq)
+
+install(
+	TARGETS	ftconvert
+	COMPONENT programs
+	ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
+	LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
+	RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
+)
+
+configure_package_config_file(
+  atidaq-config.cmake.in atidaq-config.cmake
+  INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/atidaq-${VERSION}
+)
+
+install(
+	FILES ${CMAKE_CURRENT_BINARY_DIR}/atidaq-config.cmake
+	DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/atidaq-${VERSION}
+	COMPONENT development
+)
+
+write_basic_package_version_file(
+	${CMAKE_CURRENT_BINARY_DIR}/atidaq-config-version.cmake
+	VERSION ${VERSION}
+	COMPATIBILITY ExactVersion
+)
+
+install(
+	FILES ${CMAKE_CURRENT_BINARY_DIR}/atidaq-config-version.cmake
+	DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/atidaq-${VERSION}
+	COMPONENT development
+)
+
+install(
+	EXPORT atidaq
+	DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/atidaq-${VERSION}
+	NAMESPACE atidaq::
+	FILE atidaq-export.cmake
+	COMPONENT development
+)
+
+set(CPACK_COMPONENT_DEVELOPMENT_DEPENDS runtime)
+set(CPACK_COMPONENT_PROGRAMS_DEPENDS runtime)
+set(CPACK_DEB_COMPONENT_INSTALL ON)
+set(CPACK_DEBIAN_DEVELOPMENT_PACKAGE_DEPENDS "libatidaq")
+set(CPACK_DEBIAN_DEVELOPMENT_PACKAGE_NAME "libatidaq-dev")
+set(CPACK_DEBIAN_DEVELOPMENT_PACKAGE_SECTION "libdevel")
+set(CPACK_DEBIAN_PACKAGE_HOMEPAGE "http://www.ati-ia.com/Products/ft/software/daq_software.aspx")
+set(CPACK_DEBIAN_PACKAGE_NAME "libatidaq")
+set(CPACK_DEBIAN_PACKAGE_SECTION "devel")
+set(CPACK_DEBIAN_PROGRAMS_PACKAGE_DEPENDS "libatidaq")
+set(CPACK_DEBIAN_PROGRAMS_PACKAGE_NAME "libatidaq-utils")
+set(CPACK_DEBIAN_PROGRAMS_PACKAGE_SECTION "utils")
+set(CPACK_DEBIAN_RUNTIME_PACKAGE_NAME "libatidaq")
+set(CPACK_DEBIAN_RUNTIME_PACKAGE_RECOMMENDS "libatidaq-utils")
+set(CPACK_DEBIAN_RUNTIME_PACKAGE_SECTION "libs")
+set(CPACK_NSIS_PACKAGE_NAME "ATIDAQ ${VERSION}")
+set(CPACK_NSIS_URL_INFO_ABOUT ${CPACK_DEBIAN_PACKAGE_HOMEPAGE})
+set(CPACK_PACKAGE_CONTACT "[email protected]")
+set(CPACK_PACKAGE_DISPLAY_NAME "ATIDAQ ${VERSION}")
+set(CPACK_PACKAGE_INSTALL_DIRECTORY "ATIDAQ-${VERSION}")
+set(CPACK_PACKAGE_NAME "atidaq")
+set(CPACK_PACKAGE_VERSION ${VERSION})
+set(CPACK_PACKAGE_VERSION_MAJOR ${VERSION_MAJOR})
+set(CPACK_PACKAGE_VERSION_MINOR ${VERSION_MINOR})
+set(CPACK_PACKAGE_VERSION_PATCH ${VERSION_PATCH})
+set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_SOURCE_DIR}/readme.txt)
+set(CPACK_RPM_COMPONENT_INSTALL ON)
+set(CPACK_RPM_development_PACKAGE_NAME "atidaq-devel")
+set(CPACK_RPM_development_PACKAGE_REQUIRES "atidaq")
+set(CPACK_RPM_PACKAGE_GROUP "Development/Libraries")
+set(CPACK_RPM_PACKAGE_NAME "atidaq")
+set(CPACK_RPM_PACKAGE_URL ${CPACK_DEBIAN_PACKAGE_HOMEPAGE})
+set(CPACK_RPM_programs_PACKAGE_NAME "atidaq-utils")
+set(CPACK_RPM_programs_PACKAGE_REQUIRES "atidaq")
+set(CPACK_RPM_runtime_PACKAGE_NAME "atidaq")
+set(CPACK_RPM_runtime_PACKAGE_SUGGESTS "atidaq-utils")
+
+if(WIN32 AND CMAKE_SIZEOF_VOID_P EQUAL 8)
+	set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
+endif()
+
+include(CPack)

3rdparty/atidaq/atidaq-config.cmake.in

@@ -0,0 +1,13 @@
+set(ATIDAQ_VERSION "@VERSION@")
+set(ATIDAQ_VERSION_MAJOR "@VERSION_MAJOR@")
+set(ATIDAQ_VERSION_MINOR "@VERSION_MINOR@")
+set(ATIDAQ_VERSION_PATCH "@VERSION_PATCH@")
+
+@PACKAGE_INIT@
+
+include("${CMAKE_CURRENT_LIST_DIR}/atidaq-export.cmake")
+
+set(ATIDAQ_DEFINITIONS "")
+set(ATIDAQ_INCLUDE_DIRS "")
+set(ATIDAQ_LIBRARY_DIRS "")
+set(ATIDAQ_LIBRARIES "atidaq::atidaq")