[Scratchpads] Needed packages for scratchpads and ahb peripheral bus

core/Flist.cva6

@@ -69,6 +69,9 @@ ${CVA6_REPO_DIR}/core/include/wt_cache_pkg.sv
 ${CVA6_REPO_DIR}/core/include/std_cache_pkg.sv
 ${CVA6_REPO_DIR}/core/include/instr_tracer_pkg.sv
 ${CVA6_REPO_DIR}/core/include/build_config_pkg.sv
+${CVA6_REPO_DIR}/core/include/ahb_pkg.sv
+${CVA6_REPO_DIR}/core/include/address_decoder_pkg.sv
+${CVA6_REPO_DIR}/core/include/scratchpad_pkg.sv
 
 //CVXIF
 ${CVA6_REPO_DIR}/core/include/cvxif_pkg.sv
@@ -193,4 +196,7 @@ ${CVA6_REPO_DIR}/core/cva6_mmu/cva6_ptw.sv
 ${CVA6_REPO_DIR}/core/cva6_mmu/cva6_tlb.sv
 ${CVA6_REPO_DIR}/core/cva6_mmu/cva6_shared_tlb.sv
 
+// Scratchpads
+${CVA6_REPO_DIR}/core/address_decoder/address_decoder.sv
+
 // end of manifest

core/address_decoder/address_decoder.sv

@@ -0,0 +1,76 @@
+//-----------------------------------------------------------------------------
+// Copyright 2024 Robert Bosch GmbH
+//
+// SPDX-License-Identifier: SHL-0.51
+//
+// Original Author: Coralie Allioux - Robert Bosch France SAS
+//-----------------------------------------------------------------------------
+
+module address_decoder import address_decoder_pkg::*;#(
+  parameter config_pkg::cva6_cfg_t CVA6Cfg = config_pkg::cva6_cfg_empty,
+  parameter type exception_t = logic,
+  parameter ADDR_WIDTH = 32
+) (
+  input  logic                   clk_i,
+  input  logic                   rst_ni,
+
+  input  logic                   addr_valid_i,    // Input address is valid
+  input  logic [ADDR_WIDTH-1:0]  addr_i,          // Address to be decoded
+
+  input  logic                   dscr_en_i,       // From CSR
+  input  logic                   iscr_en_i,       // From CSR
+  input  logic                   ahb_periph_en_i, // From CSR
+
+  input  logic [CVA6Cfg.XLEN-1:0] exception_code_i,
+
+  output exception_t             ex_o,
+  output addr_dec_mode_e         select_mem_o
+);
+
+  logic match_any_ahbperiph_region;
+  logic match_dscr_region;
+  logic match_iscr_region;
+  addr_dec_mode_e select_mem_n, select_mem_q;
+
+  assign match_dscr_region          = config_pkg::is_inside_data_scratchpad(CVA6Cfg, {{64-ADDR_WIDTH{1'b0}}, addr_i});
+  assign match_iscr_region          = config_pkg::is_inside_instruction_scratchpad(CVA6Cfg, {{64-ADDR_WIDTH{1'b0}}, addr_i});
+  assign match_any_ahbperiph_region = config_pkg::is_inside_ahbperiph_regions(CVA6Cfg, {{64-ADDR_WIDTH{1'b0}}, addr_i});
+
+  assign select_mem_o = select_mem_n;
+
+  always_comb begin : select_mem_p
+    ex_o = '0;
+    select_mem_n = select_mem_q;
+    if (addr_valid_i) begin
+      unique if (match_dscr_region) begin
+        // Equal to 0 only if DataScrPresent is set
+        select_mem_n = DECODER_MODE_DSCR;
+        if (!dscr_en_i) begin
+          ex_o = {exception_code_i, CVA6Cfg.XLEN'(addr_i), 1'b1};
+        end
+      end else if (match_iscr_region) begin
+        // Equal to 0 only if InstrScrPresent is set
+        select_mem_n = DECODER_MODE_ISCR;
+        if (!iscr_en_i) begin
+          ex_o = {exception_code_i, CVA6Cfg.XLEN'(addr_i), 1'b1};
+        end
+      end else if (match_any_ahbperiph_region) begin
+        select_mem_n = DECODER_MODE_AHB_PERIPH;
+        if (!ahb_periph_en_i) begin
+          ex_o = {exception_code_i, CVA6Cfg.XLEN'(addr_i), 1'b1};
+        end
+      end else begin
+        select_mem_n = DECODER_MODE_CACHE;
+      end
+    end
+  end
+
+  always_ff @(posedge clk_i or negedge rst_ni) begin : select_mem_q_p
+    if (~rst_ni) begin
+      select_mem_q <= DECODER_MODE_CACHE;
+    end else begin
+      select_mem_q <= select_mem_n;
+    end
+  end
+
+endmodule

core/include/address_decoder_pkg.sv

@@ -0,0 +1,23 @@
+//-----------------------------------------------------------------------------
+// Copyright 2024 Robert Bosch GmbH
+//
+// SPDX-License-Identifier: SHL-0.51
+//
+// Original Author: Coralie Allioux - Robert Bosch France SAS
+//-----------------------------------------------------------------------------
+
+package address_decoder_pkg;
+
+  // ----------------------
+  // Address Decoder Mode
+  // ----------------------
+
+  localparam DECODER_MODE_WIDTH = 2;
+  typedef enum logic [DECODER_MODE_WIDTH-1:0] {
+    DECODER_MODE_CACHE,
+    DECODER_MODE_DSCR,
+    DECODER_MODE_ISCR,
+    DECODER_MODE_AHB_PERIPH
+  } addr_dec_mode_e;
+
+endpackage

core/include/ahb_pkg.sv

@@ -0,0 +1,29 @@
+//-----------------------------------------------------------------------------
+// Copyright 2024 Robert Bosch GmbH
+//
+// SPDX-License-Identifier: SHL-0.51
+//
+// Original Author: Coralie Allioux - Robert Bosch France SAS
+//-----------------------------------------------------------------------------
+
+package ahb_pkg;
+
+  localparam AHBSizeWidth = 3;
+  localparam AHBTransWidth = 2;
+  localparam AHBBurstWidth = 3;
+  localparam AHBProtWidth = 4;
+
+  typedef logic [AHBSizeWidth-1:0] size_t;
+  typedef logic [AHBTransWidth-1:0] trans_t;
+  typedef logic [AHBBurstWidth-1:0] burst_t;
+  typedef logic [AHBProtWidth-1:0] prot_t;
+
+  // htrans values
+  typedef enum logic [AHBTransWidth-1:0] {
+    AHB_TRANS_IDLE,
+    AHB_TRANS_BUSY,
+    AHB_TRANS_NONSEQ,
+    AHB_TRANS_SEQ
+  } ahb_trans_e;
+
+endpackage

core/include/scratchpad_pkg.sv

@@ -0,0 +1,38 @@
+//-----------------------------------------------------------------------------
+// Copyright 2024 Robert Bosch GmbH
+//
+// SPDX-License-Identifier: SHL-0.51
+//
+// Original Author: Coralie Allioux - Robert Bosch France SAS
+//-----------------------------------------------------------------------------
+
+package scratchpad_pkg;
+
+  // ----------------------
+  // Instruction Scratchpad Mode
+  // ----------------------
+  typedef enum logic {
+    ISCR_MODE_FUNCTIONAL,
+    ISCR_MODE_PRELOAD
+  } iscr_mode_t;
+
+  // ----------------------
+  // Arbit values
+  // ----------------------
+  localparam DSCR_ARBIT_NUM_IN = 3;
+  localparam ISCR_ARBIT_NUM_IN = 4;
+
+  typedef enum logic [$clog2(ISCR_ARBIT_NUM_IN)-1:0] {
+    ISCR_ARBIT_LOAD,
+    ISCR_ARBIT_STORE,
+    ISCR_ARBIT_AHB,
+    ISCR_ARBIT_FRONTEND
+  } iscr_arbit_e;
+
+  typedef enum logic [$clog2(DSCR_ARBIT_NUM_IN)-1:0] {
+    DSCR_ARBIT_LOAD,
+    DSCR_ARBIT_STORE,
+    DSCR_ARBIT_AHB
+  } dscr_arbit_e;
+
+endpackage